$Title Blending-Problem
$Ontext

Vorlesung: Betriebliche Planung von Energiesystemen
Abschnitt: Das Blendung- und das Pooling-Problem in der Rohoelverarbeitung
Problemstellung: Maximierung der Marge eines spezifikationskonformen Blending-Programms bei sortenreiner Speicherung

 - Model -

Author: Christoph Schwindt
Date: 23/12/2019

$Offtext

$eolcom//

$include blending_data.gms

variables
   marge   Gesamte Blending-Marge (Zielfunktion)
   x(i,j)  Menge von Einsatzstoff i in Blend j ;

positive variables x ;

equations
   def_marge                    Definition der Blending-Marge
   nachfrage(j)                 Nachfrage nach Blend j
   verfuegbarkeit(i)            Verfuegbarkeit des Einsatzstoffs
   spezifikation_vol_min(j,q)   Mindestwert gemaess Spezifikationen der Qualitaet q fuer Blend j bei volumenproportionaler Mischung
   spezifikation_vol_max(j,q)   Hoechstwert gemaess Spezifikationen der Qualitaet q fuer Blend j bei volumenproportionaler Mischung
   spezifikation_gew_min(j,q)   Mindestwert gemaess Spezifikationen der Qualitaet q fuer Blend j bei gewichtsproportionaler Mischung
   spezifikation_gew_max(j,q)   Hoechstwert gemaess Spezifikationen der Qualitaet q fuer Blend j bei gewichtsproportionaler Mischung ;

   def_marge..                         marge =e= sum((i,j), (p(j)-c(i))*x(i,j)) ;
   nachfrage(j)..                      sum(i, x(i,j)) =l= d(j) ;
   verfuegbarkeit(i)..                 sum(j, x(i,j)) =l= b(i) ;
   spezifikation_vol_min(j,q)$qv(q)..  sum(i, s(i,q)*x(i,j)) =g= sUnder(j,q)*sum(i, x(i,j)) ;
   spezifikation_vol_max(j,q)$qv(q)..  sum(i, s(i,q)*x(i,j)) =l= sBar(j,q)*sum(i, x(i,j)) ;
   spezifikation_gew_min(j,q)$qw(q)..  sum(i, s(i,q)*rho(i)*x(i,j)) =l= sBar(j,q)*sum(i, rho(i)*x(i,j)) ;
   spezifikation_gew_max(j,q)$qw(q)..  sum(i, s(i,q)*rho(i)*x(i,j)) =l= sBar(j,q)*sum(i, rho(i)*x(i,j)) ;

model blending / all / ;

options lp = cplex ;

solve blending maximizing marge using lp ;

display marge.l, x.l ;