$Title Economic-Dispatch-Problem
$Ontext

Vorlesung: Betriebliche Planung von Energiesystemen
Abschnitt: 4.2 Das Economic-Dispatch-Problem
Problemstellung: Erstellung kostenminimaler Fahrplaene fuer Kraftwerksbloecke bei gegebenem Einsatzmuster

 - Model -

Author: Christoph Schwindt
Date: 20/12/2019

$Offtext

$eolcom//

$include ed_data.gms

variables
   kosten  Variable Erzeugungskosten (Zielfunktion)
   x(i,t)  Von Block i in Periode t eingespeiste elektrische Nettoleistung ;

positive variables x ;

equations
   def_kosten      Definition der Erzeugungskosten
   lastdeckung(t)  Lastdeckungsbedingung fuer Periode t ;

   def_kosten..      kosten =e= sum((i,t)$(Iu(i,t) and (not iPrime(i))), cf(i)/hi(i)*[b(i)*x(i,t)+c(i)*sqr(x(i,t))])
                                             + sum((i,t)$iPrime(i), preis(t)*x(i,t)) ;
   lastdeckung(t)..  sum(i$Iu(i,t), x(i,t)) =e= P(t) ;

   x.fx(i,t)$(not Iu(i,t)) = 0 ;
   x.lo(i,t)$Iu(i,t) = xUnder(i) ; // Einhaltung der unteren Grenze des Betriebsbereichs
   x.up(i,t)$Iu(i,t) = xBar(i) ;   // Einhaltung der oberen Grenze des Betriebsbereichs

model ed / all / ;

options qcp = cplex ;

solve ed minimizing kosten using qcp ;

display kosten.l, x.l ;