$Title Planung von Explorationsvorhaben
$Ontext

Vorlesung: Betriebliche Planung von Energiesystemen
Abschnitt: 2.1 Strategische Planung von Explorationsvorhaben
Problemstellung: Deterministische Investitions- und Finanzierungsprogrammplanung fuer Explorationsprojekte

 - Model -

Author: Florian Scholz und Rui Guo
Date: 02/12/2019

$Offtext

$eolcom//

$include exploration_data.gms

variables
   CT      Endwert des Explorationsprogramms
   e(k)    Darlehensbetrag aus Finanzierungsobjekt k
   w(j,t)  Foerdermenge aus Lagerstaette j in Periode t
   x(t)    Hoehe der am Ende von Periode t zur Verfuegung stehenden liquiden Mittel
   y(j,t)  gleich 1 falls Lagerstaette j in Periode t exploriert und erschlossen wird ;

binary variables y ;
positive variables e, w, x ;

equations
   def_CT(t)               Definition des Endwerts am Ende von Periode t = T
   cash_bilanz_init(t)     Initialisierung der Bilanzgleichungen fuer Bestand an liquiden Mitteln an Ende von Periode t=0
   cash_bilanz(t)          Bilanzgleichung fuer Bestand an liquiden Mitteln an Ende von Periode t>0
   exploration_periode(j)  Zuweisung hoechstens einer Periode fuer Exploration von Lagerstaette j
   kapazitaet(j,t)         Kapazitaetsrestriktion fuer Foerdermengen aus Lagerstaette j in Periode t
   ergiebigkeit(j)         Begrenzung der Gesamtfoerdermenge aus Lagerstaette j auf Ergiebigkeit
   fremdkapital(t)         Beschraenkung der Fremdkapitalquote in Periode t ;

   def_CT(t)$(ord(t)=card(t))..      CT =e= x(t) ;
   cash_bilanz_init(t)$(ord(t)=1)..  x(t) =e= xa + sum(k, e(k)*z(k,t)) - sum(j, ce(j)*y(j,t+1)) ;
   cash_bilanz(t)$(ord(t)>1)..       x(t) =e= (1+i(t))*x(t-1) + sum(k, e(k)*z(k,t)) + sum(j, (p(j,t)-cv(j))*w(j,t)) - sum(j$(ord(t)<card(t)), ce(j)*y(j,t+1)) ;
   exploration_periode(j)..          sum(t$(ord(t)>1), y(j,t)) =l= 1 ;
   kapazitaet(j,t)$(ord(t)>1)..      w(j,t) =l= bigR_in_t(j,t)*sum(tPrime$(ord(tPrime)<ord(t)), y(j,tPrime)) ;
   ergiebigkeit(j)..                 sum(t$(ord(t)>1), w(j,t)) =l= bigR(j) ;
   fremdkapital(t)$(ord(t)>1)..      sum(k$(sum(tPrime$((ord(tPrime)<ord(t)) and (z(k,tPrime)=1)), 1)=1), e(k)*sum(tPrime$(ord(tPrime) ge ord(t)), -z(k,tPrime)))
                                       =l= alpha*(x(t-1) + sum(j, (bigR(j)*sum(tPrime$(ord(tPrime) le ord(t)), y(j,tPrime))
                                             - sum(tPrime$(ord(tPrime)<ord(t)), w(j,tPrime))) * smin(tPrime$(ord(tPrime) ge ord(t)), p(j,tPrime)))) ;

   e.up(k) = bigE(k) ; // Beschraenkung des Darlehensbetrags aus Finanzierungsobjekt k
   w.fx(j,t)$(ord(t)=1) = 0 ;
   y.fx(j,t)$(ord(t)=1) = 0 ;

model exploration / all / ;

options mip = cplex
        optcr = 0
        reslim = 60 ;

solve exploration maximizing CT using mip ;

display CT.l, y.l, e.l, w.l, x.l ;