$Title Hydraulisches Unit-Commitment-Problem
$Ontext

Vorlesung: Betriebliche Planung von Energiesystemen
Abschnitt: 4.3 Das Unit-Commitment-Problem
Problemstellung: Kraftwerkseinsatzplanung fuer hydraulische Kraftwerksbloecke

 - Model -

Author: Christoph Schwindt
Date: 24/12/2019

$Offtext

$eolcom//

$include hydro-uc_data.gms

variables
   kosten          Gesamte Erzeugungskosten (Zielfunktion)
   r(k,i,t)        In Periode t von Turbine k-i in Periode t turbinierte bzw. negative von Pumpe k-i gepumpte Wassermenge
   u(k,t)          Betriebsstatus der Generatoren eines Speicherkraftwerks k in Periode t
   uMinus(k,t)     Betriebsstatus der Pumpen eines Pumpspeicherkraftwerks k in Periode t
   uPlus(k,t)      Betriebsstatus der Generatoren eines Pumpspeicherkraftwerks k in Periode t
   v(k,kPrime,t)   Flussstaerke von Kraftwerk k zu Kraftwerk kPrime in Periode t
   w(k,t)          Von Kraftwerk k in Periode t ueber den Ueberlauf abgelassene Wassermenge
   x(k,i,t)        In Periode t von Generator k-i eingespeiste bzw. negative von Pumpe k-i aufgenommene elektrische Leistung
   z(k,t)          Fuellstand des (Ober-)Beckens von Kraftwerk zu Beginn von Periode t ;

positive variables  v, w, z;
binary variables u, uMinus, uPlus ;

equations
   def_kosten                       Definition der Gesamtkosten
   lastdeckung(t)                   Lastdeckungsbedingung fuer Periode t
   leistung_speicher_min(k,i,t)     Einhaltung der unteren Grenze des Betriebsbereichs des Generators i des Speicherkraftwerks k
   leistung_speicher_max(k,i,t)     Einhaltung der oberen Grenze des Betriebsbereichs des Generators i des Speicherkraftwerks k
   leistung_pump_min(k,i,t)         Einhaltung der unteren Grenze des Betriebsbereichs der Pumpe bzw. des Generators i des Pumpspeicherkraftwerks k
   leistung_pump_max(k,i,t)         Einhaltung der oberen Grenze des Betriebsbereichs der Pumpe bzw. Generators i des Pumpspeicherkraftwerks k
   def_wassermenge_speicher(k,i,t)  Definition der in Periode t turbinierten Wassermengen in Turbine i des Speicherkraftwerks k
   def_wassermenge_pump(k,i,t)      Definition der in Periode t turbinierten bzw. negativen gepumpten Wassermenge in Turbine i des Pumpspeicherkraftwerks
   bilanz_wassermenge(k,t)          Bilanzgleichung fuer Fuellstand des (Ober-)Beckens von Kraftwerk k in Periode t+1
   abfluss(k,t)                     Aus (Ober-)Becken von Kraftwerk k in Periode t abfliessende Wassermenge muss vorher turbiniert oder abgelassen worden sein ;

   def_kosten..                       kosten =e= sum(t$(ord(t)<card(t)), sum(k$ks(k), cfix(k)*u(k,t)) + sum(k$kp(k), cfix(k)*(uMinus(k,t)+uPlus(k,t)))) ;
   lastdeckung(t)$(ord(t)<card(t))..  sum((k,i)$i_von_k(k,i), x(k,i,t)) =e= P(t) ;
   leistung_speicher_min(k,i,t)$(ks(k) and i_von_k(k,i) and (ord(t)<card(t)))..
                                      x(k,i,t) =g= xPlusUnder(k,i)*u(k,t) ;
   leistung_speicher_max(k,i,t)$(ks(k) and i_von_k(k,i) and (ord(t)<card(t)))..
                                      x(k,i,t) =l= xPlusBar(k,i)*u(k,t) ;
   leistung_pump_min(k,i,t)$(kp(k) and i_von_k(k,i) and (ord(t)<card(t)))..
                                      x(k,i,t) =g= xPlusUnder(k,i)*uPlus(k,t)-xMinusBar(k,i)*uMinus(k,t) ;
   leistung_pump_max(k,i,t)$(kp(k) and i_von_k(k,i) and (ord(t)<card(t)))..
                                      x(k,i,t) =l= xPlusBar(k,i)*uPlus(k,t)-xMinusUnder(k,i)*uMinus(k,t) ;
   def_wassermenge_speicher(k,i,t)$(ks(k) and i_von_k(k,i) and (ord(t)<card(t)))..
                                      r(k,i,t) =e= tau/(h(k)*g*rho)*x(k,i,t)/eta_g(k,i) ;
   def_wassermenge_pump(k,i,t)$(kp(k) and i_von_k(k,i) and (ord(t)<card(t)))..
                                      r(k,i,t) =e= tau/(h(k)*g*rho)*max(x(k,i,t)/eta_g(k,i), x(k,i,t)*eta_p(k,i)) ;
   bilanz_wassermenge(k,t)$(ord(t)<card(t))..
                                      z(k,t+1) =e= z(k,t)+s(k,t)+sum(kPrime$a(kPrime,k), v(kPrime,k,t))
                                      - sum(i$i_von_k(k,i), r(k,i,t))-w(k,t) ;
   abfluss(k,t)$(ord(t)<card(t))..    sum(kPrime$a(k,kPrime), v(k,kPrime,t)) =l= max(0, sum(i$i_von_k(k,i), r(k,i,t))+w(k,t)) ;

   z.fx(k,t)$(ord(t)=1) = za(k) ;                  // Anfangsfuellstaende
   z.fx(k,t)$(ord(t)=card(t)) = ze(k) ;            // Endfuellstaende
   z.lo(k,t)$(ord(t)>1) = zUnder(k) ;              // Mindestfuellstaende
   z.up(k,t)$(ord(t)>1) = zBar(k) ;                // Hoechstfuellstaende
   v.up(k,kPrime,t)$a(k,kPrime) = capV(k,kPrime) ; // Verbindungskapazitaeten

model hydro_uc / all / ;

options minlp = lindoglobal
        optcr = 1e-6
        reslim = 60 ;

solve hydro_uc minimizing kosten using minlp ;

display kosten.l, u.l, uMinus.l, uPlus.l, x.l, r.l, v.l, w.l, z.l ;