$Title Standortplanung regenerativer Kraftwerke
$Ontext

Vorlesung: Betriebliche Planung von Energiesystemen
Abschnitt: 2.3 Standortplanung fuer regenerative Kraftwerke
Problemstellung: Markowitz-Modell fuer das bikriterielle Standortplanungsproblem zur Maximierung des Ertrags und der Verlaesslichkeit

 - Data -

Author: Christoph Schwindt
Date: 20/12/2019

$Offtext

sets
   i      Standorte / i1*i5 /
   ex(i)  Existierende Standorte / i1*i2 /
   t      Repraesentative Perioden / t1*t12 /
   s      Jahresindizes / s1*s10 / ;

alias (i,j) ;

parameters
   a(i)             Anschlusskosten von Standort i / i3 100, i4 130, i5 80 /
   b(i)             Baukosten pro Leistungseinheit am Standort i / i1 5, i2 4, i3 4, i4 6, i5 5 /
   zUnder(i)        Mindest-Nennleistung der Anlage am Standort i / i1 50, i2 100, i3 80, i4 110, i5 70 /
   zBar(i)          Hoechstnennleistung der Anlage am Standort i / i1 250, i2 300, i3 270, i4 290, i5 110 /
   z0(i)            Installierte Nennleistung am Standort i / i1 50, i2 100, i3 0, i4 0, i5 0 /
   ausbeute(i,t,s)  Beobachtete Ausbeuten am Standort i in Periode t des Jahres j
   p(i,t)           Mittelwert der Ausbeuten am Standort i in Periode t
   c(i,j,t)         Kovarianz der Ausbeuten an Standorten i und j in Periode t ;

scalar
   capital_B  Budget fuer Investitionen in Standorte i / 3000 / ;

***** Zufaellige Erzeugung positiv korrelierter Ausbeuten *****

   scalar t_s_mean ;
   parameter mean(i) Langjaehriger Mittelwert der Ausbeute am Standort i ;

   mean(i) = uniform(0,1) ;
   loop((t,s),
         t_s_mean = uniform(0,1) ;
         ausbeute(i,t,s) = max(0, min(1, normal(2*mean(i)*t_s_mean,t_s_mean))) ;
   ) ;
   p(i,t) = 1/card(s)*sum(s, ausbeute(i,t,s)) ;
   c(i,j,t) = 1/card(s)*sum(s, (ausbeute(i,t,s)-p(i,t))*(ausbeute(j,t,s)-p(i,t))) ;