$Title Thermisches Unit-Commitment-Problem
$Ontext

Vorlesung: Betriebliche Planung von Energiesystemen
Abschnitt: 4.3 Das Unit-Commitment-Problem
Problemstellung: Kraftwerkseinsatzplanung fuer thermische Kraftwerksbloecke
Quelle: Tafeluebung Vorlesung Betriebliche Planung von Energiesystemen, Aufgabe 13

 - Data -

Author: Rui Guo und Christoph Schwindt
Date: 20/12/2019

$Offtext

sets
   i          Bloecke / steinkohle, pumpspeicher, braunkohle, spotmarkt /
   therm(i)   Thermische Bloecke / steinkohle, braunkohle /
   iPrime(i)  Spotmarkt / spotmarkt /
   t          Perioden / t0*t12 / ;

alias (t,tPrime) ;

parameters
   xUnder(i)  Untergrenze des Betriebsbereichs von Block i / steinkohle 400, pumpspeicher 200, braunkohle 500, spotmarkt 0 /
   xBar(i)    Obergrenze des Betriebsbereichs von Block i / steinkohle 800, pumpspeicher 500, braunkohle 1000 /
   xStar(i)   Nennleistung von Block i
   gBar(i)    Durchschnittskosten der Erzeugung bei Nennleistung / steinkohle 100, pumpspeicher 130, braunkohle 80 /
   u0(i)      Initialer Betriebsstatus von Block i / steinkohle 1, pumpspeicher 0, braunkohle 1, spotmarkt 1 /
   delta0(i)  Mindeststillstandszeit von Block i / steinkohle 3, pumpspeicher 2, braunkohle 10, spotmarkt 1 /
   delta1(i)  Mindestbetriebszeit von Block i / steinkohle 3, pumpspeicher 3, braunkohle 3, spotmarkt 1 /
   cfix(i)    Fixe Betriebskosten von Block i / steinkohle 10000, pumpspeicher 0, braunkohle 20000, spotmarkt 0 /
   con(i)     Anfahrkosten von Block i / steinkohle 30, pumpspeicher 10, braunkohle 100, spotmarkt 0 /
   coff(i)    Abfahrkosten von Block i / steinkohle 15, pumpspeicher 5, braunkohle 50, spotmarkt 0 /
   beta(i,t)  Koeffizient vor linearem Term in Approximation der Erzeugungskosten von Block i
   gamma(i)   Koeffizient vor quadratischem Term in Approximation der Erzeugungskosten von Block i
   P(t)       In Periode t zu deckende Last / t1 1800, t2 1600, t3 2000, t4 1500, t5 1400, t6 1300, t7 1300, t8 1000,
                                              t9 500, t10 500, t11 500, t12 1200 /
   R(t)       Regelreserve
   preis(t)   Prognose fuer Gleichgewichtspreis auf Spotmarkt in Periode t / t1*t12 140 / ;

scalar
   alpha  Anteil der Regelreserve / 0.3 / ;

   xBar(i)$iPrime(i) = sum(t, P(t)) ;
   xStar(i)$therm(i) = (1-alpha)*xBar(i) ;
   xStar(i)$(not therm(i)) = xBar(i) ;

   R(t)$(ord(t)>1) = alpha*P(t) ;
   gamma(i)$therm(i) = cfix(i)/sqr(xStar(i)) ; // gewaehrleistet, dass bei Nennleistung Durchschnittskosten minimal sind
   gamma(i)$(not therm(i)) = 0 ;
   beta(i,t)$((ord(t)>1) and (not iPrime(i))) = gBar(i) - 2*cfix(i)/xStar(i) ; // gewaehrleistet, dass Durchschnittskosten der Erzeugung bei Nennleistung gBar betragen
   beta(i,t)$((ord(t)>1) and iPrime(i)) = preis(t) ;