$Title Timetabling
$Ontext

Vorlesung: Distributionslogistik
Abschnitt: 2.5 Timetabling in Hub-and-Spoke-Netzwerken
Problemstellung: Erstellung eines Linienfahrplans fuer Fernverkehrstransporte in einem Hub-and-Spoke-Netzwerk
Hinweis: zweistufiges Single- oder Multiple-Allocation-Netzwerk mit vollstaendigem Hub-Netz, ohne Hub-Bypassing

 - Data -

Author: Christoph Schwindt
Date: 18/11/2019

$Offtext

sets
   i       Knoten des Netzwerks / i1*i8 /
   dep(i)  Depots / i1*i6 /
   hub(i)  Hubs / i7*i8 /
   t       Perioden / t1*t19 /
   l       Fahrzeugtypen / lkw, flugzeug / ;

alias (i,iPrime,j), (dep,h,k), (t,tPrime) ;

sets
   a(i,j)                   Pfeilmenge des Netzwerks / (i1*i3).i7, (i1,i4*i6).i8, i7.(i1*i3), i8.(i1,i4*i6), i7.i8, i8.i7 /
   arc_on_paths(h,k,i,j)    Menge der Pfeile auf Wegen von Depot h zu Depot k
   arc_with_vehicle(i,j,l)  Menge der Pfeile mit Fahrzeugen vom Typ l
   node_with_vehicle(i,l)   Menge der Knoten mit Fahrzeugen vom Typ l ;

parameters
   b(h,k,t)      Im Depot h in Periode t zum Versand an Depot k bereitgestellte Menge
                 / i1.i2.t8 6, i1.i3.t8 4, i1.i4.t1 2, i1.i5.t1 3, i1.i6.t1 4
                   i2.i1.t8 3, i2.i3.t8 7, i2.i4.t1 3, i2.i5.t1 2, i2.i6.t1 1
                   i3.i1.t8 2, i3.i2.t8 3, i3.i4.t1 5, i3.i5.t1 4, i3.i6.t1 2
                   i4.i5.t8 6, i4.i6.t8 9, i4.i1.t1 4, i4.i2.t1 5, i4.i3.t1 5
                   i5.i4.t8 3, i5.i6.t8 2, i5.i1.t1 8, i5.i2.t1 2, i5.i3.t1 4
                   i6.i4.t8 7, i6.i5.t8 5, i6.i1.t1 2, i6.i2.t1 5, i6.i3.t1 3 /
   b_hat(h,k,t)  Von Depot k aus in Periode t an Empfaenger verteilte Menge aus Depot h
   c(l)          Fixkosten bei Einsatz eines Fahrzeug des Typs l / lkw 10, flugzeug 50 /
   p(i,j,l)      Transportzeit in Perioden von i nach j mit Fahrzeug des Typs l
                 / (i1*i3).i7.lkw 3, (i1,i4*i6).i8.lkw 4, i7.(i1*i3).lkw 3, i8.(i1,i4*i6).lkw 4, i7.i8.flugzeug 2, i8.i7.flugzeug 2 /
   q(i,l)        Umschlagsdauer in Perioden der Ladung eines Fahrzeugs des Typs l in Hub i / (i7*i8).lkw 1, (i7*i8).flugzeug 2 /
   r(i,l)        Kapazitaetsbedarf pro Periode fuer Umschlag der Ladung von Fahrzeugtyp l in Hub i / (i7,i8).lkw 1, (i7,i8).flugzeug 1 /
   u(i,t)        Umschlagskapazitaet von Hub i in Periode t / i7.(t1*t18) 10, i8.(t1*t18) 12 /
   v(l)          Ladekapazitaet eines Fahrzeug vom Typ l / lkw 5, flugzeug 11 / ;

* computation of remaining entries

   b_hat(h,k,t)$((not sameas(h,k)) and (ord(t)=card(t))) = sum(tPrime, b(h,k,tPrime)) ;

   arc_on_paths(h,k,i,j) = no;
   arc_on_paths(h,k,i,j)$(a(i,j) and sameas(h,i) and (not sameas(h,k))) = yes ;
   arc_on_paths(h,k,i,j)$(a(i,j) and sameas(k,j) and (not sameas(h,k))) = yes ;
   arc_on_paths(h,k,i,j)$(a(h,i) and a(i,j) and a(j,k) and (not sameas(h,k))) = yes ;

   arc_with_vehicle(i,j,l) = no ;
   arc_with_vehicle(i,j,'lkw')$(a(i,j) and (dep(i) or dep(j))) = yes ;
   arc_with_vehicle(i,j,'flugzeug')$(a(i,j) and hub(i) and hub(j)) = yes ;

   node_with_vehicle(i,l) = no ;
   node_with_vehicle(i,l)$(sum(j$(arc_with_vehicle(i,j,l) or arc_with_vehicle(j,i,l)), 1) > 0) = yes ;

scalar epsilon / 1e-3 / ;