$Title Pufferverteilung fuer Reihenfertigungssysteme
$Ontext

Vorlesung: Modellierung und Planung von Logistiksystemen
Abschnitt: 3.2 Konfigurationsplanung bei Fliessfertigung
Problemstellung: Verteilung einer gegebenen Anzahl von Pufferplaetzen auf die Zellen eines Fliessfertigungssystems
                 bei Poissonschen Ankuenften und exponentialverteilten Bearbeitungsdauern
Hinweis: Implementierung des Modells ist auf dreistufige Systeme ausgerichtet

 - Data -

Author: Christoph Schwindt
Date: 08/12/2019

$Offtext

sets
   k   Zellen  / k1*k3 /
   ik  Zustaende der individuellen Zellen / 0*6 / ;

alias (ik,i1,i2,i3,j1,j2,j3) ;

set i(i1,i2,i3)  Zustandsraum ;

   i(i1,i2,i3) = yes ;

alias (i,j) ;

scalars
   w        Stueckdeckungsbeitrag / 1 /
   h        Lagerungskostensatz / 0 /
   ges_kap  Gesamtkapazitaet / 10 /
   lambda   Externe Ankunftsrate / 100 / ;

parameters
   mu(k)                 Bearbeitungsrate in Zelle k / k1 100, k2 100, k3 100 /
   g(i1,i2,i3,j1,j2,j3)  Uebergangsrate von Zustend i zu Zustand j
   zBar(k)               Obere Schranke fuer Pufferkapazitaet von Zelle k ;

   zBar(k) = card(ik)-2 ;

***** Setze Uebergangsraten *****

   g(i,j) = 0 ;
   g(i1,i2,i3, i1+1,i2,i3)$(ord(i1)<card(i1)) = lambda ;
   g(i1,i2,i3, i1-1,i2+1,i3)$((ord(i1)>1) and (ord(i2)<card(i2))) = mu('k1') ;
   g(i1,i2,i3, i1,i2-1,i3+1)$((ord(i2)>1) and (ord(i3)<card(i3))) = mu('k2') ;
   g(i1,i2,i3, i1,i2,i3-1)$(ord(i3)>1) = mu('k3') ;