$Title Grenzleistung von Stetigfoerderern
$Ontext

Vorlesung: Modellierung und Planung von Logistiksystemen
Abschnitt: 4.1 Konfigurationsplanung von Foerdersystemen
Problemstellung: Maximierung der Foerderleistung eines Systems von Stetigfoerderern
Quelle: Tafeluebung zur Vorlesung, Aufgabe 13

 - Data -

Author: Christoph Schwindt
Date: 21/12/2019

$Offtext

sets
   i     Knoten des Foerdersystems / Q1*Q3, V4*V6, Z13*Z14, S1*S4 /
   Q(i)  Quellen / Q1*Q3 /
   S(i)  Senken / S1*S4 /
   V(i)  Verzweigungselemente / V4*V6 /
   Z(i)  Zusammenfuehrungselemente / Z13*Z14 /
   f     Foerderstrecken / F1*F3, F7*F12, F15*F16 / ;

alias (i,j,jPrime), (f,g) ;

set
   a(f,i,j)  Topologie des Foerdersystems / F1.Q1.V4, F2.Q2.V5, F3.Q3.V6, F7.V4.S1, F8.V4.Z13, F9.V5.Z13,
                                            F10.V5.S3, F11.V6.Z14, F12.V6.Z14, F15.Z13.S2, F16.Z14.S4 / ;

parameters
   gamma(f)  Grenzdurchsatz Forderstrecke f / F1 1, F2 0.5, F3 1, F7 0.5, F8 1, F9 1, F10 0.5, F11 0.5, F12 1 / ;

   gamma('F15') = smax(f, gamma(f)) ;
   gamma('F16') = gamma('F15') ;

parameters
   ts(i,f,g)         Schaltzeit von Element i von Foerderstrecke f auf Forderstrecke g
                     / V4.F7.F8 20, V4.F8.F7 20, Z14.F11.F12 1, Z14.F12.F11 1 /
   x(i,f)            Auf Element i fuer Foerderstrecke f gleichzeitig bewegte Menge
                     / V4.F7 2, V4.F8 2, V5.F9 6, V5.F10 6, V6.F11 1, V6.F12 1, Z13.F8 1, Z13.F9 1, Z14.F11 2, Z14.F12 2 /
   t(i,f)            Foerder- bzw. Spielzeit von Element i fuer Forderstrecke f
                     / V4.F7 5, V4.F8 5, V5.F9 6, V5.F10 9, V6.F11 1, V6.F12 5, Z13.F8 1, Z13.F9 3, Z14.F11 5, Z14.F12 5 /
   piUnder(i,f)      Vorgegebener Mindest-Richtungsanteil fuer Verzweigungselement i und Foerderstrecke f
                     / V4.F7 0.5, V4.F8 0.5, V5.F9 0.3, V5.F10 0.7, V6.F11 0.7, V6.F12 0.3 /
   piBar(i,f)        Vorgegebener Hoechst-Richtungsanteil fuer Verzweigungselement i und Foerderstrecke f
                     / V4.F7 0.5, V4.F8 0.5, V5.F9 0.3, V5.F10 0.7, V6.F11 0.7, V6.F12 0.3 /
   gamma_tilde(f,i)  Partieller Grenzdurchsatz von Element i fuer Forderstrecke f ;

   gamma_tilde(f,i)$(sum(j, a(f,i,j)) and V(i)) = x(i,f)/t(i,f) ; // Verzweigungselemente
   gamma_tilde(f,i)$(sum(j, a(f,j,i)) and Z(i)) = x(i,f)/t(i,f) ; // Zusammenfuehrungselemente