$Title Grenzleistung von Stetigfoerderern
$Ontext

Vorlesung: Modellierung und Planung von Logistiksystemen
Abschnitt: 4.1 Konfigurationsplanung von Foerdersystemen
Problemstellung: Maximierung der Foerderleistung eines Systems von Stetigfoerderern

 - Model -

Author: Christoph Schwindt
Date: 21/12/2019

$Offtext

$eolcom//

$include cont-conveyor_data.gms

variables
   durchsatz       Grenzdurchsatz (Zielfunktion)
   lambda_arc(f)   Betrieblicher Durchsatz auf Foerderstrecke f
   lambda_node(i)  Betrieblicher Durchsatz durch Element i ;

positive variables lambda_arc, lambda_node ;

equations
   def_durchsatz                      Definition des Grenzdurchsatzes
   flusserhaltung(i)                  Flusserhaltungsbedingung an Verzweigungs- oder Zusammenfuehrungselement i
   def_lambda_node(i)                 Definition der Flussstaerke durch Element i
   durchsatz_foerderstrecken(f,i,j)   Durchsatzbedingung fuer Foerderstrecke f von Knoten i zu Knoten j
   durchsatz_verzweigung(i)           Durchsatzbedingung fuer Verzweigungselement i
   durchsatz_zusammenfuehrung(i)      Durchsatzbedingung fuer Zusammenfuehrungselement i
   mindest_richtungsanteil(i,f)       Einhaltung des Mindest-Richtungsanteils fuer Verzweigungselement i und Foerderstrecke f
   hoechst_richtungsanteil(i,f)       Einhaltung des Hoechst-Richtungsanteils fuer Verzweigungselement i und Foerderstrecke f ;

   def_durchsatz..                                            durchsatz =e= sum((f,i,j)$(a(f,i,j) and Q(i)), lambda_arc(f));
   flusserhaltung(i)$(V(i) or Z(i))..                         sum((f,j)$a(f,j,i), lambda_arc(f)) =e= sum((f,j)$a(f,i,j), lambda_arc(f)) ;
   def_lambda_node(i)$(V(i) or Z(i))..                        lambda_node(i) =e= sum((f,j)$a(f,i,j), lambda_arc(f)) ;
   durchsatz_foerderstrecken(f,i,j)$a(f,i,j)..                lambda_arc(f) =l= gamma(f) ;
   durchsatz_verzweigung(i)$V(i)..                            sum((f,j)$a(f,i,j), lambda_arc(f)*sum((g,jPrime)$a(g,i,jPrime),
                                                                 lambda_arc(g)*(1/gamma_tilde(f,i)+ts(i,f,g)))) =l= lambda_node(i) ;
   durchsatz_zusammenfuehrung(i)$Z(i)..                       sum((f,j)$a(f,j,i), lambda_arc(f)*sum((g,jPrime)$a(g,jPrime,i),
                                                                 lambda_arc(g)*(1/gamma_tilde(f,i)+ts(i,f,g)))) =l= lambda_node(i) ;
   mindest_richtungsanteil(i,f)$(sum(j,a(f,i,j)) and V(i))..  lambda_arc(f) =g= piUnder(i,f)*sum((g,jPrime)$a(g,i,jPrime), lambda_arc(g)) ;
   hoechst_richtungsanteil(i,f)$(sum(j,a(f,i,j)) and V(i))..  lambda_arc(f) =l= piBar(i,f)*sum((g,jPrime)$a(g,i,jPrime), lambda_arc(g)) ;

model cont_conveyor / all / ;

options nlp = baron  // lindoglobal liefert lokales Minimum
        optcr = 1e-6
        reslim = 60 ;

solve cont_conveyor maximizing durchsatz using nlp ;

display durchsatz.l, lambda_arc.l, lambda_node.l ;