$Title Konfiguration von Unstetigfoerderern
$Ontext

Vorlesung: Modellierung und Planung von Logistiksystemen
Abschnitt: 4.1 Konfigurationsplanung von Foerdersystemen
Problemstellung: Auswahl und Orientierung von Forderstrecken bei gegebenen Gaengen in einer Halle
Quelle: Abbildung des Layouts einer Werkshalle und der Orientierung des Gang-Graphen aus dem Foliensatz zur Vorlesung

 - Data -

Author: Christoph Schwindt
Date: 16/12/2019

$Offtext

sets
   i     Kreuzungen sowie Eingaenge und Ausgaenge der Stationen / C1*C6, IO1, IO4, I2*I3, O2*O3 /
   k(i)  Ausgaenge / IO1, IO4, O2*O3 /
   l(i)  Eingaenge / IO1, IO4, I2*I3 / ;

alias (i,j) ;

set
   e(i,j)     Menge ungerichteter Strecken
              / C1.C3, C1.IO1, C1.I2, C2.C3, C2.IO1, C2.O3, C3.C4, C4.C5, C4.IO4, C5.C6, C5.O2, C6.IO4, C6.I3, I2.O2, I3.O3 /
   aBar(i,j)  Menge aller moeglichen Foerderstrecken ;

   aBar(i,j) = no ;
   aBar(i,j)$(e(i,j) or e(j,i)) = yes ;

scalar
   ratioFix2Var  Verhaeltnis von fixen zu variablen Kosten / 3 / ;

parameters
   c(i,j)     Variable Foerderkosten pro Fahrt auf Verbindung i-j
              / C1.C3 8, C1.IO1 12, C1.I2 9, C2.C3 7, C2.IO1 3, C2.O3 11, C3.C4 6, C4.C5 12, C4.IO4 3, C5.C6 19, C5.O2 15, C6.IO4 4, C6.I3 7, I2.O2 2, I3.O3 2 /
   cfix(i,j)  Fixe Einrichtungskosten auf der Verbindung i-j pro Periode
   b(i,k)     Angebotsrate an beladenen Foerderzeugen die in k starten ;

   c(i,j)$(c(j,i)>0) = c(j,i) ;
   cfix(i,j)$aBar(i,j) = ratioFix2Var*c(i,j) ;

table
   s(k,l)  Vorgegebene Foerderrate von Ausgang k zu Eingang l
         IO1    I2     I3      IO4
   IO1   0      5      2       7
   O2    6      0      1       1
   O3    3      4      0       8
   IO4   11     5      6       0  ;

   b(k,k) = sum(l, s(k,l)) ;
   b(l,k)$s(k,l) = -s(k,l) ;

scalar
   bigM  Hinreichend grosse Konstante ;

   bigM = sum(k, b(k,k)) ;