$Title Konfiguration von Unstetigfoerderern
$Ontext

Vorlesung: Modellierung und Planung von Logistiksystemen
Abschnitt: 4.1 Konfigurationsplanung von Foerdersystemen
Problemstellung: Auswahl und Orientierung von Forderstrecken bei gegebenen Gaengen in einer Halle

 - Model -

Author: Rui Guo
Date: 16/12/2019

$Offtext

$eolcom//

$include disc-conveyor_data.gms

variables
   kosten    Gesamtkostenrate (Zielfunktion)
   w(i,j)    Rate der Leerfahrten auf Foerderstrecke i-j pro Periode
   x(i,j,k)  Rate der Vollfahrten auf Foerderstrecke i-j pro Periode die in Ausgang k starten
   y(i,j)    gleich 1 falls Verbindung i-j eingerichtet und von i nach j orientiert wird ;

positive variables w, x ;
binary variables y ;

equations
   gesamtkostenrate             Definition der Gesamtkostenrate
   flusserhaltung_voll(i,k)     Flusserhaltungsbedingung fuer Knoten i und von Station k ausgehenden Vollfahrten
   flusserhaltung_voll_leer(i)  Flusserhaltungsbedingung fuer Knoten i fuer Voll- und Leerfahrten
   def_y(i,j)                   Definition der Binaervariable y fuer Strecke i-j
   orientierung(i,j)            Bedingung zur Orientierung der Strecke i-j ;

   gesamtkostenrate..             kosten =e= sum((i,j)$aBar(i,j), sum(k, x(i,j,k))+w(i,j)) + sum((i,j)$aBar(i,j), cfix(i,j)*y(i,j)) ;
   flusserhaltung_voll(i,k)..     sum(j$aBar(i,j), x(i,j,k)) - sum(j$aBar(j,i), x(j,i,k)) =e= b(i,k) ;
   flusserhaltung_voll_leer(i)..  sum(j$aBar(i,j), sum(k, x(i,j,k))+w(i,j)) =e= sum(j$aBar(j,i), sum(k, x(j,i,k))+w(j,i)) ;
   def_y(i,j)$aBar(i,j)..         sum(k, x(i,j,k)) + w(i,j) =l= bigM*y(i,j) ;
   orientierung(i,j)$e(i,j)..     y(i,j)+y(j,i) =l= 1 ;

model disc_conveyor / all / ;

options mip = cplex
        optcr = 0
        reslim = 60 ;

solve disc_conveyor using mip minimzing kosten ;

display kosten.l, y.l, x.l, w.l ;