$Title Single-Allocation Hub-Location-Problem
$Ontext

Vorlesung: Modellierung und Planung von Logistiksystemen
Abschnitt: 2.3 Standortplanung in Hub-and-Spoke-Netzwerken
Problemstellung: Planung der Standorte von Hubs und deren Verbindungen bei 1:n Hub-Depot-Relationen

 - Model -

Author: Christoph Schwindt
Date: 25/12/2019

$Offtext

$eolcom//

$include hub-location_data.gms

variables
   kosten           Gesamtkosten fuer Transporte sowie Einrichtung und Betrieb von Hubs und deren Verbindungen (Zielfunktion)
   x(i,iPrime,j)    Von Hub i zu Hub iPrime versandte Menge aus Depot j
   y_hub(i)         gleich 1 falls Hub i eingerichtet wird
   y_rel(i,iPrime)  gleich 1 falls Transportrelation zwischen Hubs i und iPrime eingerichtet wird
   z(i,j)           gleich 1 falls Depot j an Hub i angebunden wird ;

positive variables x ;
binary variables y_hub, y_rel, z ;

equations
   def_kosten                     Definition der Gesamtkosten
   depot_hub(j)                   Zuordnung von Depot j zu Hubs
   flusserhaltung(i,j)            Flusserhaltungsbedingung fuer in Hubs i umgeschlagene Sendungen aus Depot j
   umschlagskapazitaet(i)         Umschlagskapazitaet in Hub i
   transportkapazitaet(i,iPrime)  Transportkapazitaet auf Transportrelation zwischen Hubs i und iPrime ;

   def_kosten..                                          kosten =e= sum[(i,j), {c(j,i)*sum(jPrime, b(j,jPrime))+c(i,j)*sum(jPrime, b(jPrime,j))}*z(i,j)
                                                                       + sum(iPrime$(not sameas(iPrime,i)), c(i,iPrime)*x(i,iPrime,j))]
                                                                       + sum(i, cfix_hub(i)*y_hub(i))
                                                                       + sum((i,iPrime)$(ord(i)<ord(iPrime)), cfix_rel(i,iPrime)*y_rel(i,iPrime)) ;
   depot_hub(j)..                                        sum(i, z(i,j)) =e= 1 ;
   flusserhaltung(i,j)..                                 sum(jPrime, b(j,jPrime))*z(i,j) + sum(iPrime$(not sameas(iPrime,i)), x(iPrime,i,j)) =e=
                                                            sum(iPrime$(not sameas(iPrime,i)), x(i,iPrime,j)) + sum(jPrime, b(j,jPrime)*z(i,jPrime)) ;
   umschlagskapazitaet(i)..                              sum(j, sum(jPrime, b(j,jPrime))*z(i,j) + sum(iPrime$(not sameas(iPrime,i)), x(iPrime,i,j))) =l= a(i)*y_hub(i) ;
   transportkapazitaet(i,iPrime)$(ord(i)<ord(iPrime))..  sum(j, x(i,iPrime,j) + x(iPrime,i,j)) =l= sum((j,jPrime), b(j,jPrime))*y_rel(i,iPrime) ;

model hub_location_1 / all / ;

options mip = cplex
        optcr = 0
        reslim = 60 ;

solve hub_location_1 minimzing kosten using mip ;

display kosten.l, y_hub.l, y_rel.l, z.l, x.l ;