$Title Multiple-Allocation Hub-Location-Problem
$Ontext

Vorlesung: Modellierung und Planung von Logistiksystemen
Abschnitt: 2.3 Standortplanung in Hub-and-Spoke-Netzwerken
Problemstellung: Planung der Standorte von Hubs und deren Verbindungen bei m:n Hub-Depot-Relationen

 - Model -

Author: Christoph Schwindt
Date: 25/12/2019

$Offtext

$eolcom//

$include hub-location_data.gms

variables
   kosten               Gesamtkosten fuer Transporte sowie Einrichtung und Betrieb von Hubs und deren Verbindungen (Zielfunktion)
   x(node,nodePrime,j)  Von Knoten node zu Knoten nodePrime versandte Menge aus Depot j
   y_hub(i)             gleich 1 falls Hub i errichtet wird
   y_rel(i,iPrime)      gleich 1 falls Transportrelation zwischen Hubs i und iPrime eingerichtet wird ;

positive variables x ;
binary variables y_hub, y_rel ;

equations
   def_kosten                     Definition der Gesamtkosten
   versandmenge(j)                Verteilung der Versandmenge aus Depot j auf verbundene Hubs
   flusserhaltung(i,j)            Flusserhaltungsbedingung fuer in Hub i umgeschlagene Sendungen aus Depot j
   ausliefermenge(j,jPrime)       Zusammenfuehrung der Versandmengen aus Depot j fuer Depot jPrime
   umschlagskapazitaet(i)         Umschlagskapazitaet in Hub i
   transportkapazitaet(i,iPrime)  Transportkapazitaet auf Transportrelation zwischen Hubs i und iPrime ;

   def_kosten..                                          kosten =e= sum[j, sum(i, c(j,i)*x(j,i,j)) + sum((i,iPrime)$(not sameas(i,iPrime)), c(i,iPrime)*x(i,iPrime,j))
                                                            + sum((iPrime,jPrime), c(iPrime,jPrime)*x(iPrime,jPrime,j))]
                                                            + sum(i, cfix_hub(i)*y_hub(i)) + sum((i,iPrime)$(ord(i)<ord(iPrime)), cfix_rel(i,iPrime)*y_rel(i,iPrime)) ;
   versandmenge(j)..                                     sum(i, x(j,i,j)) =e= sum(jPrime, b(j,jPrime)) ;
   flusserhaltung(i,j)..                                 x(j,i,j) + sum(iPrime$(not sameas(iPrime,i)), x(iPrime,i,j)) =e=
                                                            sum(iPrime$(not sameas(iPrime,i)), x(i,iPrime,j)) + sum(jPrime, x(i,jPrime,j)) ;
   ausliefermenge(j,jPrime)$(not sameas(j,jPrime))..     sum(iPrime, x(iPrime,jPrime,j)) =e= b(j,jPrime) ;
   umschlagskapazitaet(i)..                              sum(j, x(j,i,j) + sum(iPrime$(not sameas(iPrime,i)), x(iPrime,i,j))) =l= a(i)*y_hub(i) ;
   transportkapazitaet(i,iPrime)$(ord(i)<ord(iPrime))..  sum(j, x(i,iPrime,j) + x(iPrime,i,j)) =l= sum((j,jPrime), b(j,jPrime))*y_rel(i,iPrime) ;

model hub_location_m / all / ;

options mip = cplex
        optcr = 0
        reslim = 60 ;

solve hub_location_m minimzing kosten using mip ;

display kosten.l, y_hub.l, y_rel.l, x.l ;