$Title Quadratisches Zuordnungsproblem
$Ontext

Vorlesung: Modellierung und Planung von Logistiksystemen
Abschnitt: 2.4 Layoutplanung
Problemstellung: Zuweisung von Betriebseinheiten zu Standorten zur Minimierung des Foerderaufwands

 - Model -

Author: Rui Guo
Date: 10/12/2019

$Offtext

$eolcom//

$include qap_data.gms

variables
   aufwand  Foerderaufwand (Zielfunktion)
   x(i,k)   gleich 1 falls Betriebseinheit i Standort k zugewiesen wird ;

binary variables x ;

equations
   def_aufwand     Definition des Foerderaufwands
   standort_BE(i)  Zuweisung eines Standorts zu Betriebseinheit i
   BE_standort(k)  Zuweisung einer Betriebseinheit zu Standort k ;

   def_aufwand..     aufwand =e= sum((i,j)$(ord(i)<ord(j)), sum((k,l)$(not sameas(k,l)), r(i,j)*d(k,l)*x(i,k)*x(j,l))) ;
   standort_BE(i)..  sum(k, x(i,k)) =e= 1 ;
   BE_standort(k)..  sum(i, x(i,k)) =e= 1 ;

model qap / all / ;

options miqcp = cplex
        optcr = 0
        reslim = 60 ;

solve qap minimzing aufwand using miqcp ;

display aufwand.l, x.l ;