$Title Warehouse-Location-Problem (einstufig)
$Ontext

Vorlesung: Modellierung und Planung von Logistiksystemen
Abschnitt: 2.1 Standortplanung in Distributionsnetzwerken
Problemstellung: Planung von Auslieferungslagern und Transportmengen in einem Distributionsnetzwerk

 - Model -

Author: Rui Guo
Date: 29/10/2019

$Offtext

$eolcom//

$include wlp-1_data.gms

variables
   kosten  Gesamtkosten (Zielfunktion)
   x(i,j)  Transportmenge von Lager i in Verkaufsgebiet j
   y(i)    gleich 1 wenn Lager i errichtet wird ;

positive variable x ;
binary variable y ;

equations
   def_kosten    Definition der Gesamtkosten
   nachfrage(j)  Befriedigung der Nachfrage in Verkaufgebiet j
   angebot(i)    Beschraenkung der Liefermenge aus Lager i auf Angebotsmenge ;

   def_kosten..    kosten =e= sum((i,j), d(i,j)*x(i,j)) + sum(i, cfix(i)*y(i)) ;
   nachfrage(j)..  sum(i, x(i,j))=e= b(j) ;
   angebot(i)..    sum(j, x(i,j)) =l= a(i)*y(i) ;

model wlp / all / ;

options mip = cplex
        optcr = 0
        reslim = 60 ;

solve wlp minimzing kosten using mip ;

display kosten.l, y.l, x.l ;