$Title Warehouse-Location-Problem (mehrstufig)
$Ontext

Vorlesung: Modellierung und Planung von Logistiksystemen
Abschnitt: 2.1 Standortplanung in Distributionsnetzwerken
Problemstellung: Planung von Lagern und Transportmengen in einem Distributionsnetzwerk

 - Model -

Author: Rui Guo
Date: 30/10/2019

$Offtext

$eolcom//

$include wlp-m_data.gms


variables
   kosten       Gesamtkosten (Zielfunktion)
   x(k,kPrime)  Transportmenge von Knoten k zu Knoten kPrime
   y(k)         gleich 1 falls Lager k errichtet wird ;

positive variables x ;
binary variables y ;

equations
   def_kosten                Definition der Gesamtkosten
   produktionskapazitaet(h)  Einhaltung der Produktionskapazitaet von Werk h
   flusserhaltung(k)         Flusserhaltungsbedingung fuer inneren Knoten k
   umschlagskapazitaet(k)    Einhaltung der Umschlagskapazitaet von Lager k
   nachfrage(j)              Nachfragebefriedigung in Verkaufsgebiet j ;

   def_kosten..                                   kosten =e= sum((k, kPrime)$arcs(k,kPrime), d(k,kPrime)*x(k,kPrime))
                                                               + sum(k$(not (h(k) or j(k))), cfix(k)*y(k)) ;
   produktionskapazitaet(h)..                     sum(kPrime$arcs(h,kPrime), x(h,kPrime)) =l= a(h) ;
   flusserhaltung(k)$(not (h(k) or j(k)))..       sum(kPrime$arcs(kPrime,k), x(kPrime,k)) =e= sum(kPrime$arcs(k,kPrime), x(k,kPrime)) ;
   umschlagskapazitaet(k)$(not (h(k) or j(k)))..  sum(kPrime$arcs(k,kPrime), x(k,kPrime)) =l= a(k)*y(k) ;
   nachfrage(j)..                                 sum(kPrime$arcs(kPrime,j),x(kPrime,j)) =e= b(j) ;

model wlp_m / all / ;

options mip = cplex
        optcr = 0
        reslim = 60 ;

solve wlp_m minimzing kosten using mip ;

display kosten.l, y.l, x.l ;