$Title  Termin- und Kapazitaetsplanung als ressourcenbeschraenkte Projektplanung
$Ontext

Vorlesung: Produktionswirtschaft
Abschnitt: 7.1 Termin- und Kapazitaetsplanung in der Einzel- und Kleinserienfertigung
Problemstellung: Minimierung der Dauer eines Projekts unter Vorrangbeziehungen und Ressourcenbeschraenkungen

 - Data -

Foliensatz

Author: Rui Guo
Date: 03/12/2019

$Offtext

sets
   h   Aktivitaeten / h0*h6 /
   t   Zeitpunkte / t0*t30 /
   i   Erneuerbare Ressourcen / i1 /
   j   Kumulative Ressourcen / j1 / ;

alias (h,g,hPrime), (t,tPrime) ;

set a(g,h)  Verallgemeinerte Vorrangbeziehungen (Pfeile) / h0.(h1,h3,h5), h1.(h2,h6), h2.(h1,h6), h3.(h0,h4,h5), h4.(h3,h6), h5.(h4,h6), h6.h0 / ;

parameter
     p(h)     Dauer von Aktivitaet h / h0 0, h1 6, h2 4, h3 2, h4 4, h5 7, h6 0 /
     ES(h)    Fruehester Startzeitpunkt von Aktivitaet h
     LS(h)    Spaetester Startzeitpunkt von Aktivitaet h
     ri(h,i)  Inanspruchnahme der erneuerbaren Ressource i durch Aktivitaet h / h0.i1 0, h1.i1 1, h2.i1 1, h3.i1 2, h4.i1 1, h5.i1 2, h6.i1 0 /
     rj(h,j)  Inanspruchnahme der kumulativen Ressource j durch Aktivitaet h / h0.j1 4, h1.j1 -1, h2.j1 1, h3.j1 4, h4.j1 -1, h5.j1 -2, h6.j1 0 /
     R(i)     Kapazitaet von Ressource i / i1 5 / ;

table
   delta(g,h)  Zeitlicher Mindestabstand zwischen den Startzeitpunkten der Aktivitaeten g und h
          h0     h1     h2     h3     h4     h5     h6
   h0            0             0             0
   h1                   1                           6
   h2            -3                                 4
   h3     -1                          0      -2
   h4                          -1                   4
   h5                                 2             7
   h6     -9                                           ;

parameter dist(g, h)  Distanzmatrix ;

   dist(g,h) = -inf ;
   dist(g,g) = 0 ;
   dist(g,h)$a(g,h) = delta(g,h) ;
   loop(hPrime,
         loop((g,h),
                 if ((dist(g,hPrime)>-inf) and (dist(hPrime,h)>-inf),
                         if (dist(g,h) < dist(g,hPrime)+dist(hPrime,h), dist(g,h) = dist(g,hPrime)+dist(hPrime,h); );
                 );
         );
   );

   ES(h) = dist('h0', h) ;
   LS(h) = -dist(h,'h0') ;

display ES, LS ;