$Title Termin- und Kapazitaetsplanung als ressourcenbeschraenkte Projektplanung
$Ontext

Vorlesung: Produktionswirtschaft
Abschnitt: 7.1 Termin- und Kapazitaetsplanung in der Einzel- und Kleinserienfertigung
Problemstellung: Minimierung der Dauer eines Projekts unter Vorrangbeziehungen und Ressourcenbeschraenkungen

 - Model -

Author: Rui Guo
Date: 03/12/2019

$Offtext

$eolcom//

$include crcpspmax_data.gms

   variables
   Cmax    Projektdauer (Zielfunktion)
   x(h,t)  gleich 1 wenn Aktivitaet h zum Zeitpunkt t startet ;

   binary variables x ;

   equations
   def_Cmax             Definition der Projektdauer
   startzeitpunkt(h)    Zuweisung eines Startzeitpunkts zu Aktivitaet h
   zeitabstand(g,h,t)   Einhaltung des zeitlichen Mindestabstands zwischen Aktivitaeten g und h in Periode t
   kapazitaet(i,t)      Kapazitaetsrestriktion fuer erneuerbare Ressource i
   verfuegbarkeit(j,t)  Verfuegbarkeitsrestriktion fuer kumulative Ressource j ;

   def_Cmax..                     Cmax =e= sum((t,h)$(ord(h)=card(h)), (ord(t)-1)*x(h,t)) ;
   startzeitpunkt(h)..            sum(t$((ord(t)-1 le LS(h)) and (ord(t)-1 ge ES(h))), x(h,t)) =e= 1 ;
   zeitabstand(g,h,t)$(a(g,h))..  sum(tPrime$((ord(tPrime)-1 le LS(g)) and (ord(tPrime)-1 ge max(ES(g),ord(t)-1))), x(g,tPrime))
                                    + sum(tPrime$((ord(tPrime)-1 le min(LS(h),ord(t)+ delta(g,h)-2)) and (ord(tPrime)-1 ge ES(h))), x(h,tPrime)) =l= 1 ;
   kapazitaet(i,t)..              sum(h, ri(h,i)*sum(tPrime$((ord(tPrime)-1 le min(LS(h),ord(t)-1)) and (ord(tPrime)-1 ge max(ES(h),ord(t)-p(h)))), x(h,tPrime))) =l= R(i) ;
   verfuegbarkeit(j,t)..          sum(h$(rj(h,j)<0), rj(h,j)*sum(tPrime$((ord(tPrime)-1 le min(LS(h),ord(t)-1)) and (ord(tPrime)-1 ge ES(h))), x(h,tPrime)))
                                    + sum(h$(rj(h,j)>0), rj(h,j)*sum(tPrime$((ord(tPrime)-1 le min(LS(h),ord(t)-p(h))) and (ord(tPrime)-1 ge ES(h))), x(h,tPrime))) =g= 0 ;

   model crcpspmax / all / ;

   options mip = cplex
           optcr = 0
           reslim = 60 ;

   solve crcpspmax using mip minimzing Cmax ;

   display Cmax.l, x.l ;