$Title Dynamische Produktionsprogrammplanung
$Ontext

Vorlesung: Produktionswirtschaft
Abschnitt: 4.1 Produktionsprogrammplanung
Problemstellung: Mehrperiodige Maximierung des Deckungsbeitrags des Produktionsprogramms

 - Model -

Author: Rui Guo
Date: 05/11/2019

$Offtext

$eolcom//

$include dynamic-mps_data.gms

variables
   DB      Deckungsbeitrag (Zielfunktion)
   y(j,t)  Produktionsmenge von Produktgruppe j in Periode t
   x(j,t)  Lagerbestand von Produktgruppe j zu Beginn von Periode t
   z(j,t)  Absatzmenge von Produktgruppe j in Periode t ;

positive variables x, y, z ;

equations
   def_DB            Definition Deckungsbeitrag
   kapazitaet(i,t)   Kapazitaetsrestriktion fuer Faktor i und Periode t
   lagerbilanz(j,t)  Lagerbilanzgleichung fuer Bestand von Produktgruppe j in Periode t+1 ;

   def_DB..                    DB =e= sum((j,t)$real(t), p(j)*z(j,t)-k(j)*y(j,t)-h(j)*x(j,t+1)) ;
   kapazitaet(i,t)$real(t)..   sum(j, a(i,j)*y(j,t)) =l= R(i,t) ;
   lagerbilanz(j,t)$real(t)..  x(j,t+1) =e= x(j,t)+y(j,t)-z(j,t) ;

   z.up(j,t) = d(j,t) ;            // Absatzbeschraenkung fuer Produktgruppe j
   x.fx(j,t)$(ord(t)=1) = xa(j) ;  // Initialisierung des Lagerstands an Produktgruppe j zu Beginn von Periode 1

model dynamic_mps / all / ;

options lp = cplex ;

solve dynamic_mps maximizing DB using lp ;

display DB.l, y.l, z.l, x.l ;