$Title MLCLSP-Modell (Multi-Level Capacitated Lotsizing Problem)
$Ontext

Vorlesung: Produktionswirtschaft
Abschnitt: 6.3 Deterministische dynamische Modelle (der Bestellmengen- und Losgroessenplanung)
Problemstellung: Ermittlung optimaler periodenbezogener Losgroessen fuer eine mehrstufige Erzeignisstruktur unter Kapazitaetsrestriktionen

 - Data -

Author: Rui Guo
Date: 25/11/2019

$Offtext

sets
   i  Maschinentyp / i1*i4 /
   j  Produkte / j1*j4 /
   t  Perioden / t1*t6 / ;

alias (t,tPrime), (j,k) ;

parameters
   R(i,t)      Produktionskapazitaet von Maschinentyp i in Periode t / i1.(t1*t6) 60, i2.(t1*t6) 70, i3.(t1*t6) 45, i4.(t1*t6) 55 /
   theta(i,j)  Ruestzeit von Produkt j auf Maschinentyp i / i1.j1 10, i2.j2 5, i3.j3 3, i4.j4 6 /
   Kfix(j)     Fixe Ruestkosten von Produkt j / j1 20, j2 12, j3 10, j4 8 /
   h(j)        Lagerungskostenansatz von Produkt j / j1 0.02, j2 0.05, j3 0.02, j4 0.01 /
   a(j,k)      Direktbedarfskoeffizient von Produkt j fuer Produkt k / j2.j1 1, j4.j1 1, j3.j2 1, j4.j2 2 /
   et(i,j)     Einzelzeit von Produkt j auf Maschinentyp i / i1.j1 10, i2.j2 5, i3.j3 3, i4.j4 6 / ;

table d(j,t)  Primaerbedarf an Produkt j in Periode t
         t1 t2 t3 t4 t5 t6
    j1   0  1  1  3  4  0
    j2   0  0  0  1  1  0
    j3   0  4  2  0  0  0
    j4   0  0  3  0  3  0 ;

***** Gleichungssystem fuer Stuecklistenaufloesung *****

variables
   null    Dummy-Zielfunktionswert
   z(j,t)  Gesamtbedarf an Produkt j in Periode t ;

positive variables z ;

equations
   konstante              Dummy-Zielfunktion
   def_gesamtbedarf(j,t)  Definition des Gedamtbedarfs fuer Produkt j in Periode t ;

   konstante..              null =e= 0 ;
   def_gesamtbedarf(j,t)..  z(j,t) =e= d(j,t) + sum(k$a(j,k), a(j,k)*z(k,t)) ;

model stuecklistenaufloesung / all / ;

solve stuecklistenaufloesung minimizing null using lp ;