$Title MLCLSP-Modell (Multi-Level Capacitated Lotsizing Problem)
$Ontext

Vorlesung: Produktionswirtschaft
Abschnitt: 6.3 Deterministische dynamische Modelle (der Bestellmengen- und Losgroessenplanung)
Problemstellung: Ermittlung optimaler periodenbezogener Losgroessen fuer eine mehrstufige Erzeignisstruktur unter Kapazitaetsrestriktionen

 - Model -

Author: Rui Guo
Date: 25/11/2019

$Offtext

$eolcom//

$include mlclsp_data.gms

variables
   kosten      Gesamtkosten (Zielfunktion)
   q(j,t)      Losgroesse von Produkt j in Periode t
   delta(j,t)  gleich 1 wenn in Periode t Los fuer Produkt j aufgelegt wird
   x(j,t)      Lagerbestand von Produkt j zu Beginn von Periode t ;

positive variables q, x ;
binary variables delta ;

equations
   def_kosten        Definition der Gesamtkosten
   def_delta(j,t)    Definition der Delta-Variable fuer Produkt j und Periode t
   kapazitaet(i,t)   Kapazitaetsbeschraenkung fuer Maschinentyp i und Periode t
   lagerbilanz(j,t)  Lagerbilanzgleichung fuer Produkt j und Periode t+1 ;

   def_kosten..                         kosten =e= sum((j,t)$(ord(t)<card(t)), Kfix(j)*delta(j,t)+h(j)*x(j,t+1)) ;
   def_delta(j,t)$(ord(t)<card(t))..    delta(j,t)*sum(tPrime$(ord(tPrime) ge ord(t)), z.l(j,tPrime)) =g= q(j,t) ;
   kapazitaet(i,t)..                    sum(j, theta(i,j)*delta(j,t)+ et(i,j)*q(j,t)) =l= R(i,t) ;
   lagerbilanz(j,t)$(ord(t)<card(t))..  x(j,t+1) =e= x(j,t)+q(j,t)-sum(k$a(j,k), a(j,k)*q(k,t))-d(j,t) ;

   x.fx(j,t)$(ord(t)=1) = 0 ;

model mlclsp / all / ;

options mip = cplex
        optcr = 0
        reslim = 60 ;

solve mlclsp minimzing kosten using mip ;

display kosten.l, delta.l, q.l, x.l ;