$Title Fliessbandabgleich
$Ontext

Vorlesung: Produktionswirtschaft
Abschnitt: 3.3 Infrastrukturmassnahmen
Problemstellung: Taktischer Fliessbandabgleich bei gegebener Taktzeit

 - Model -

Author: Rui Guo
Date: 18/09/2019

$Offtext

$eolcom//

$include salbp-1_data.gms

variable
   m        Anzahl Arbeitsstationen (Zielfunktion)
   x(i,mu)  gleich 1 wenn Operation o_mu Station i zugewiesen wird ;

binary variables x ;


equations
   def_m(mu)                     Definition der Anzahl benoetigter Arbeitsstationen
   operation_arbeitsstation(mu)  Zuweisung einer Arbeitsstation fuer Operation o_mu
   taktzeit(i)                   Beschraenkung des Arbeitsinhalts von Station i auf die Taktzeit
   vorrang(lambda,mu)            Vorrangbeziehung zwischen Operationen o_lambda und o_mu ;

   def_m(mu)..                           m =g= sum(i, ord(i)*x(i,mu)) ;
   operation_arbeitsstation(mu)..        sum(i, x(i,mu)) =e= 1 ;
   taktzeit(i)..                         sum(mu, p(mu)*x(i,mu)) =l= tau ;
   vorrang(lambda,mu)$prec(lambda,mu)..  sum(i, ord(i)*x(i,lambda)) =l= sum(i, ord(i)*x(i,mu)) ;

model salbp_1 / all / ;

options mip = cplex
        optcr = 0
        reslim = 60 ;

solve salbp_1 minimzing m using mip ;

display m.l, x.l ;