$Title Stochastisches EOQ-Modell
$Ontext

Vorlesung: Produktionswirtschaft
Abschnitt: 6.4 Stochastische Modelle
Problemstellung: Modell zur Optimierung einer (s,q)-Politik unter normalverteiltem Periodenbedarf bei Vormerkung und Fehlmengenkostensatz

 - Model -

Author: Christoph Schwindt
Date: 14/12/2019

$Offtext

$eolcom//

$include stoch-eoq_data.gms

variables
   C   Erwartete Gesamtkostenrate (Zielfunktion)
   s   Bestellpunkt
   q   Bestellmenge
   L1  Erwartete Fehlmenge ;

positive variables L1, s, q ;

equations
   def_C   Definition der erwarteten Gesamtkostenrate
   def_L1  Definition der Verlustfunktion L1 ;

   def_C..   C  =e= K*d/q + h*(q/2+s) + (p1*d/q)*L1 ;
   def_L1..  L1 =e= (1/sqrt(2*pi)*exp(-sqr((s-mu)/sigma)/2)-(s-mu)/sigma*(1-errorf((s-mu)/sigma)))*sigma ;

model stoch_eoq / all / ;

options minlp = lindoglobal
        optcr = 1e-6
        reslim = 60 ;

   s.up = 1000 ; // Schranken fuer den Solver
   q.lo = 1e-5 ; q.up = 1000 ; // Schranken fuer den Solver

solve stoch_eoq using minlp minimzing C ;

scalars
   sb     Sicherheitsbestand
   alpha  Servicegrad vom Typ 1
   beta   Servicegrad vom Typ 2 ;

   sb = s.l - mu ;
   alpha = errorf((s.l-mu)/sigma) ;
   beta = 1-L1.l/q.l ;

display s.l, q.l, C.l, sb, alpha, beta ;