$Title (Delta,S)-Politik
$Ontext

Vorlesung: Supply Chain Management
Abschnitt: 2.3 Modelle der einstufigen Beschaffungsplanung
Problemstellung: Modell zur Optimierung einer (Delta,S)-Politik unter normalverteiltem Periodenbedarf

 - Model -

Author: Christoph Schwindt
Date: 06/03/2019

$Offtext

$eolcom//

$include Delta-S_data.gms

variables
   C        Erwartete Gesamtkostenrate (Zielfunktion)
   Delta    Bestellrhythmus
   S        Bestellgrenze
   mu_Y     Erwarteter Bedarf im Risikozeitraum
   sigma_Y  Standardabweichung des Bedarfs im Risikozeitraum ;

positive variables Delta, S, mu_Y, sigma_Y ;

equations
   def_C        Definition der erwarteten Gesamtkostenrate
   servicegrad  Bedingung zur Einhaltung des beta-Servicegrads
   def_mu_Y     Definition des erwarteten Bedarfs im Risikozeitraum
   def_sigma_Y  Definition der Standardabweichung des Bedarfs im Risikozeitraum ;

   def_C..         C  =e= h*(S-(L+Delta/2)*d)+k/Delta ;
   servicegrad..   (1/sqrt(2*pi)*exp(-sqr((S-mu_Y)/sigma_Y)/2)-(S-mu_Y)/sigma_Y*(1-errorf((S-mu_Y)/sigma_Y)))*sigma_Y =l= (1-beta)*Delta*d ;
   def_mu_Y..      mu_Y =e= (L+Delta)*d ;
   def_sigma_Y..   sigma_Y =e= sqrt(L+Delta)*sigma_D ;

model Delta_S / all / ;

options minlp = lindoglobal
        optcr = 1e-6
        reslim = 60 ;

* Schranken fuer den Solver
   S.lo = 1e-5 ; S.up = 1000 ;
   Delta.lo = 1e-5 ; Delta.up = 1000 ;
   mu_Y.lo = (L+Delta.lo)*d ; mu_Y.up = (L+Delta.up)*d ;
   sigma_Y.lo = sqrt(L+Delta.lo)*sigma_D ; sigma_Y.up = sqrt(L+Delta.up)*sigma_D ;

solve Delta_S using minlp minimzing C ;

scalar sb Sicherheitsbestand ;

   sb = S.l - (L+Delta.l)*d ;

display C.l, Delta.l, S.l, sb ;