$Title Newsvendor-Modell
$Ontext

Vorlesung: Supply Chain Management
Abschnitt: 2.3 Modelle der einstufigen Beschaffungsplanung
Problemstellung: Einperiodige Bestellmengenplanung unter normalverteiltem Periodenbedarf

 - Model -

Author: Christoph Schwindt
Date: 24/11/2019

$Offtext

$eolcom//

$include newsvendor_data.gms

variables
   kosten  Summe aus erwarteten Ueber- und Unterbestandskosten
   q       Bestellmenge
   z       Standardisierte Bestellmenge
   t       Hilfsgroesse zur Approximation der Normalverteilung
   pdf     Wert der Verteilungsdichte der Standardnormalverteilung an der Stelle z
   cdf     Approximierter Wert der Verteilungsfunktion der Standardnormalverteilung an der Stelle z >= 0

positive variables q, z, t, pdf, cdf ;

equations
   def_kosten  Definition der erwarteten Gesamtkosten
   def_z       Definition von z
   def_t       Definition von t(z)
   def_pdf     Defintion der Verteilungsdichte phi
   def_cdf     Definition der approximierten Verteilungsfunktion Phi ;

   def_kosten..  kosten =e= (pi-piPrime)*(q-mu)+(p-piPrime)*(pdf*sigma-(q-mu)*(1-cdf)) ;
   def_z..       z =e= (q-mu)/sigma ;
   def_t..       t =e= 1/(1+0.33267*z) ;
   def_pdf..     pdf =e= 1/sqrt(2*3.14159265)*exp(-0.5*sqr(z)) ;
   def_cdf..     cdf =e= 1 - pdf*(0.4361836*t - 0.1201676*sqr(t) + 0.9372980*power(t,3)) ;

model newsvendor / all / ;

options nlp = lindoglobal
        optcr = 1e-6
        reslim = 60 ;

   t.up = 1 ;
   pdf.up = 1/sqrt(2*3.1415926) ;
   cdf.up = 1 ;

solve newsvendor minimzing kosten using nlp ;

display kosten.l, q.l ;