$Title Masterplanung
$Ontext

Vorlesung: Supply Chain Management
Abschnitt: 4.3 Masterplanung
Problemstellung: Zentrale Koordination der Wertschoepfung und der Gueterfluesse entlang der Supply Chain
Quelle: Abbildung einer Supply Chain mit mehrstufiger Erzeugnis- und Distributionsstruktur aus Foliensatz zur Vorlesung

 - Data -

Author: Christoph Schwindt
Date: 29/12/2019

$Offtext

sets
   i               Supply-Chain-Partner / P1*P3, D1*D3 /
   d(i)            Haendler (Distributionslager) / D1*D3 /
   p(i)            Produzenten (Produktionsstaetten) / P1*P3 /
   k               Engpassanlagen / F1*F6 /
   k_at_p(k,p)     Engpassanlagen bei Produzent p / (F1,F2).P1, F3.P2, (F4*F6).P3 /
   j               Schluesselprodukte der Supply Chain / j1*j4 /
   j_from_i(i,j)   Von Partner i gelieferte Produkte j
   j_prod_p(i,j)   Bei Produzent p produzierte Produkte j / P1.j3, P2.j3, P3.j4 /
   j_to_i_sc(i,j)  An Partner i innerhalb der Supply Chain gelieferte Produkte j
   j_to_i_ex(i,j)  Von Partner i von ausserhalb bezogene Produkte j / P3.j1, P2.j2, D1.j4 /
   j_at_i(i,j)     Bei Partner i produzierte bzw. gehandelte oder verbrauchte Produkte j
   t               Perioden / t1*t13 / ; // Letzte Periode ist Dummy-Periode T+1

alias (i,iPrime), (j,jPrime), (p,pPrime), (d,dPrime) ;

sets
   l(i,iPrime,j)   Lieferbeziehungen / P3.P1.(j1,j2), P1.P3.j3, P2.P3.(j2,j3), P2.D1.j3, P3.D1.j4, D1.(D2*D3).(j3,j4) / ;

   j_from_i(i,j)  = sum(iPrime, l(i,iPrime,j)) ;
   j_to_i_sc(i,j) = sum(iPrime, l(iPrime,i,j)) ;
   j_at_i(i,j)    = j_from_i(i,j) + j_prod_p(i,j) + j_to_i_sc(i,j) + j_to_i_ex(i,j) ;

parameters
   a(j,jPrime)        Direktbedarfskoeffizient von Produkt j fuer Produkt jPrime / j1.j2 1, j1.j3 2, j2.j3 3, j2.j4 2, j3.j4 1 /
   cb(i,j)            Einstandsstueckkosten von Produkt j fuer Partner i / P3.j1 1, P2.j2 13, D1.j4 93 /
   co(p)              Kosten fuer eine Ueberstunde bei Produzent p / P1 1.5, P2 1, P3 3 /
   cm(p,j)            Herstell- bzw. Fertigungsstueckkosten von Produkt j Produzent p / P1.j3 2, P2.j3 1, P3.j4 9 /
   cs(i,iPrime,j)     Transportstueckkosten von Produkt j bei Lieferung von Partner i an Partner iPrime
                      / P3.P1.(j1,j2) 0.1, P1.P3.j3 0.2, P2.P3.j2 0.1, P2.P3.j3 0.2, P2.D1.j3 0.1, P3.D1.j4 0.1, D1.(D2*D3).(j3,j4) 0.4 /
   h(i,j)             Lagerungskostensatz von Produkt bei j bei Partner i
                      / P1.j1 0.1, P1.j2 0.14, P1.j3 0.8, P2.j2 0.15, P2.j3 0.7, P3.j1 0.09, P3.j2 0.13, P3.j3 0.75, P3.j4 0.9,
                        D1.j3 0.8, D1.j4 1, (D2,D3).j3 0.9, (D2,D3).j4 1.1 /
   bigR_pers(p,t)     Personal-Normalkapazitaet von Produzent p in Periode t
                      / P1.(t1*t12) 75, P2.(t1*t12) 40, P3.(t1*t12) 150 /
   bigRBar_pers(p,t)  Personal-Maximalkapazitaet von Produzent p in Periode t
   bigR_fac(k,t)      Produktionskapazitaet von Anlage k in Periode t
                      / F1.(t1*t12) 70, F2.(t1*t12) 75, F3.(t1*t12) 50, F4.(t1*t12) 150, F5.(t1*t12) 200, F6.(t1*t12) 150 /
   req_pers(p,j)      Personalbedarf pro ME von Produkt j bei Produzent p
                      / P1.j3 2, P2.j3 1.5, P3.j4 4.5 /
   req_fac(k,j)       Kapazitaetsbedarf pro ME von Produkt j an Anlage k
                      / F1.j3 2, F2.j3 2, F3.j3 1, F4.j4 3, F5.j4 4, F6.j4 2 /
   xUnder(i,j)        Sicherheitsbestand von Produkt j bei Partner i
                      / P1.j1 5, P1.j2 7, P2.j2 10, P3.j2 15, P3.j3 5, D1.j3 10, D1.j4 40, (D2,D3).j3 5, (D2,D3).j4 20 /
   xa(i,j)            Koerperlicher Anfangslagerbestand von Produkt j bei Partner i
                      / P1.j1 11, P1.j2 9, P2.j2 23, P3.j2 31, P3.j3 40, D1.j3 19, D1.j4 67, (D2,D3).j3 23, (D2,D3).j4 21 / ;

   bigRBar_pers(p,t) = 1.25*bigR_pers(p,t) ;


table
   dem(d,j,t)  Nachfrage nach Produkt j in Einzugsbereich von Haendler d in Periode t
            t1      t2      t3      t4      t5      t6      t7      t8      t9      t10     t11     t12
   D2.j3    3       4       6       8       6       9       11       9      8       12      6       10
   D2.j4    23      19      17      25      36      33      29      28      35      27      14      31
   D3.j3    5       2       1       4       5       51      7        9      6       7       11      5
   D3.j4    40      32      59      21      55      5       43       1      4       45      27      3 ;