$Title Preisorientierte Kapazitaetssteuerung
$Ontext

Vorlesung: Service Operations Management
Abschnitt: 3.1 Revenue Management
Problemstellung: Ermittlung von Bid-Preisen fuer einzelne Fluege einer Menge von Verbindungen

 - Model -

Author: Christoph Schwindt
Date: 21/12/2019

$Offtext

$eolcom//

$include bid-prices_data.gms

variables
   umsatz  Umsatz aus Verkauf der Verbindungen
   x(w)    Anzahl verkaufter Sitzplaetze fuer Verbindung w ;

positive variables x ;

equations
   def_umsatz     Definition des Umsatzes
   kapazitaet(j)  Fluggastkapazitaet des Flugs j ;

   def_umsatz..     umsatz =e= sum(w, pBar(w)*x(w)) ;
   kapazitaet(j)..  sum(w$j_auf_w(j,w), x(w)) =l= R(j) ;

   x.up(w) = q(w) ;

model bid_prices / all / ;

options lp = cplex ;

solve bid_prices maximizing umsatz using lp ;

parameters
   bidpreis_flug(j)        Bid-Preis des Flugs j
   bidpreis_verbindung(w)  Bid-Preis der Verbindung w ;

   bidpreis_flug(j) = kapazitaet.m(j) ;
   bidpreis_verbindung(w) = sum(j$j_auf_w(j,w), bidpreis_flug(j)) ;

display umsatz.l, x.l, bidpreis_flug, bidpreis_verbindung ;