$Title Strategische Kapazitaetsplanung
$Ontext

Vorlesung: Service Operations Management
Abschnitt: 3.3 Strategische Kapazitaetsplanung
Problemstellung: Dimensionierung des Warteraums und der Bedienungsstation eines Markovschen Wartesystems

 - Model -

Author: Christoph Schwindt
Date: 28/02/2022

$Offtext

$eolcom//

$include capacity-planning_data.gms

variables
   BE             Erwartetes Betriebsergebnis
   lambda_eff     Effektive Ankunfsrate
   g(i,j)         Uebergangsrate von Zustand i zu Zustand j
   pi(i)          Stationaere Wahrscheinlichkeit von Zustand i
   z(i,j)         Hilfsvariable = g*pi*y
   C              Warteraum
   s              Anzahl Bedienungsschalter
   anz_belegt(i)  Anzahl belegter Warteschlangenplaetze in Zustand i
   y(i)           Indikatorvariablen y ;

positive variables  pi, g, z, anz_belegt ;
binary variables    y ;
integer variables   C, s ;

equations
   def_BE             Definition des erwarteten Betriebsergebnisses
   eff_ankunftsrate   Berechnung der effektiven Ankunfsrate
   def_g_1(i)         Definition von g(ij) fuer Zustaende i und j=i-1 Teil 1
   def_g_2(i)         Definition von g(ij) fuer Zustaende i und j=i-1 Teil 2
   def_z_1(i,j)       Definition von z(ij) fuer Zustaende i und j Teil 1
   def_z_2(i,j)       Definition von z(ij) fuer Zustaende i und j Teil 2
   def_z_3(i,j)       Definition von z(ij) fuer Zustaende i und j Teil 3
   gleichgewicht(i)   Gleichgewichtsbedingungen fuer Zustand i
   norm               Normierungsbedingung
   def_y_1(i)         Definition von y(i) fuer Zustand i Teil 1
   def_y_2(i)         Definition von y(i) fuer Zustand i Teil 2
   def_pi(i)          Definition von pi(i) fuer Zustand i
   def_anz_belegt(i)  Definition von anz_belegt fuer Zustand i
   auslastung         Begrenzung der Auslastung der Bedienungsschalter
   belegungsgrad      Begrenzung des Belegungsgrads der Warteschlange ;

   def_BE..                 BE =e= w*lambda_eff*T - c_buf*(C-s) - c_serv*s ;
   eff_ankunftsrate..       lambda_eff =e= sum(i$(ord(i)<card(i)), z(i,i+1)) ;
   def_g_1(i)$(ord(i)>1)..  g(i,i-1) =l= (ord(i)-1)*mu ;
   def_g_2(i)$(ord(i)>1)..  g(i,i-1) =l= s*mu ;
   def_z_1(i,j)$n(i,j)..    z(i,j) =g= g(i,j)*pi(i) - g(i,j)*(1-y(j)) ;
   def_z_2(i,j)$n(i,j)..    z(i,j) =l= g(i,j)*pi(i) ;
   def_z_3(i,j)$n(i,j)..    z(i,j) =l= g(i,j)*y(j) ;
   gleichgewicht(i)..       sum(j$n(i,j), z(i,j)) =e= sum(j$n(j,i), z(j,i)) ;
   norm..                   sum(i, pi(i)) =e= 1 ;
   def_y_1(i)..             y(i) =l= 1-(ord(i)-1-C)/(cBar-1) ;
   def_y_2(i)..             y(i) =g= (C+1-ord(i)+1)/(cBar+1) ;
   def_pi(i)..              pi(i) =l= y(i) ;
   def_anz_belegt(i)..      anz_belegt(i) =g= (ord(i)-1)-s ;
   auslastung..             lambda_eff/mu =l= rho_bar_s*s ;
   belegungsgrad..          sum(i, pi(i)*anz_belegt(i)) =l= rho_bar_w*(C-s) ;

   C.lo = 1; C.up = cBar ; s.lo = 1; s.up = sBar ;
   g.fx(i,j)$(not n(i,j)) = 0 ; z.fx(i,j)$(not n(i,j)) = 0 ;
   g.fx(i,i+1)$(ord(i)<card(i)) = lambda*epsilon(i) ;

model capacity_planning / all / ;

options miqcp = gurobi
        optcr = 1e-6
        reslim = 60 ;

file opt 'gurobi options file' / gurobi.opt / ;
putclose opt 'nonConvex = 2'/ ;

capacity_planning.optfile = 1 ;

solve capacity_planning using miqcp maximizing BE ;

scalars
   auslastung_real     realisierte Auslastung Bedienungsstationen
   belegungsgrad_real  realisierter Belegungsgrad Warteschlange ;

   auslastung_real = lambda_eff.l/(s.l*mu) ;
   if (C.l>s.l,
      belegungsgrad_real = sum(i$(ord(i)-1>s.l), pi.l(i)*(ord(i)-1-s.l))/(C.l-s.l);
   else
      belegungsgrad_real = 0 ;
   ) ;

display BE.l, s.l, C.l, pi.l, lambda_eff.l, auslastung_real, belegungsgrad_real ;