$Title Data-Envelopment-Analyse
$Ontext

Vorlesung: Service Operations Management
Abschnitt: 1.3 Messung und Vergleich der Dienstleistungsproduktivitaet
Problemstellung: Effizienzvergleich von Einheiten bei konstanten (marginalen) Skalenertraegen

 - Model -

Author: Christoph Schwindt
Date: 21/12/2019

$Offtext

$eolcom//

$include dea_data.gms

***** DEA-Modell *****

variables
   pi_l     Relativer Effizienzwert von Einheit l (Zielfunktion)
   mu_l(j)  Transformiertes Aggregationsgewicht (Preis) von Ausbringung j bei Einheit l
   nu_l(i)  Transformiertes Aggregationsgewicht (Preis) von Faktor i bei Einheit l ;

positive variables mu, nu ;

parameters
   r_l(i)  Einsatzmenge von Faktor i bei betrachteter Einheit l
   x_l(j)  Produktionsmenge von Ausbringung j bei betrachteter Einheit l ;

equations
   def_pi                 Definition des Effizienzwerts von Einheit l
   effizienzvergleich(k)  Beschraenkung der Effizenz von Einheit k bei Verwendung der Preise von Einheit l
   charnes_cooper         Gleichung fuer die Charnes-Cooper-Transformation ;

   def_pi..                 pi_l =e= sum(j, x_l(j)*mu_l(j)) ;
   effizienzvergleich(k)..  sum(j, x(j,k)*mu_l(j)) =l= sum(i, r(i,k)*nu_l(i)) ;
   charnes_cooper..         sum(i, r_l(i)*nu_l(i)) =e= 1 ;

model dea / def_pi, effizienzvergleich, charnes_cooper / ;

options lp = cplex ;

   dea.solprint = 2 // Unterdruecke automatische Ausgaben in Listing-File

*******************************
***** Ruecktransformation *****

variables
   null    Konstante (Zielfunktion)
   v_l(i)  Preis des Faktors i
   u_l(j)  Preis der Ausbringung j ;

positive variables u_l, v_l ;

equations
   def_null      Setze null auf 0
   compute_v(i)  Berechne Preis des Faktors i
   compute_u(j)  Berechne Preis der Ausbringung j
   norm          Normiere Preise um triviale Loesung v=0 auszuschliessen ;

   def_null..      null =e= 0 ;
   compute_v(i)..  v_l(i) =e= nu_l.l(i)*sum(iPrime, r_l(iPrime)*v_l(iPrime)) ;
   compute_u(j)..  u_l(j) =e= mu_l.l(j)*sum(i, r_l(i)*v_l(i)) ;
   norm..          sum(i, r_l(i)*v_l(i)) =e= 1 ;  // Hierdurch ergibt sich v=nu und u=mu

model transformation / def_null, compute_v, compute_u, norm / ;

   transformation.solprint = 2 // Unterdruecke automatische Ausgaben in Listing-File

*********************************************
***** Effizenzvergleich aller Einheiten *****

parameters
   pi(l)        Effienzwert von Einheit l
   v(i,l)       Preis von Faktor i bei Einheit l
   u(j,l)       Preis von Ausbringung j bei Einheit l
   lambda(k,l)  Gewicht von Input r(k) in Input der virtuellen Einheit l' von Einheit l ;

   loop(l,
         r_l(i) = r(i,l) ;
         x_l(j) = x(j,l) ;
         solve dea maximizing pi_l using lp ;
         pi(l) = pi_l.l ;
         lambda(k,l) = effizienzvergleich.m(k) ;
         solve transformation maximizing null using lp ;
         v(i,l) = v_l.l(i) ;
         u(j,l) = u_l.l(j) ;
   ) ;

display pi, v, u, lambda ;