$Title Flow-Capturing-Modell
$Ontext

Vorlesung: Service Operations Management
Abschnitt: 2.2 Planung von Standorten und Netzwerken
Problemstellung: Standortplanung bei Impulskaufverhalten

 - Model -

Author: Christoph Schwindt
Date: 21/12/2019

$Offtext

$eolcom//

$include flow-capturing_data.gms

variables
   flussstaerke  Gesamtstaerke der Fluesse denen eine Einheit zugeordnet wurde (Zielfunktion)
   x(j,w)        gleich 1 falls Einheit an Knoten j Fluss auf Weg w zugeordnet wird
   y(j)          gleich 1 falls am Knoten j eine Einheit errichtet wird ;

binary variables x, y ;

equations
   def_flussstaerke  Definition der Gesamtflussstaerke
   fluss_einheit(w)  Zuordnung von hoechstens einer Einheit zu Fluss w
   kopplung(j)       Einheit an Knoten j kann Fluessen nur zugeordnet werden wenn sie errichtet wurde
   anzahl            Festlegung der Anzahl an zu errichtenden Einheiten ;

   def_flussstaerke..  flussstaerke =e= sum(w, h(w)*sum(j$j_auf_w(j,w), x(j,w))) ;
   fluss_einheit(w)..  sum(j$j_auf_w(j,w), x(j,w)) =l= 1 ;
   kopplung(j)..       sum(w$j_auf_w(j,w), x(j,w)) =l= card(w)*y(j) ;
   anzahl..            sum(j, y(j)) =e= p ;

model flow_capturing / all / ;

options mip = cplex
        optcr = 0
        reslim = 60 ;

solve flow_capturing maximizing flussstaerke using mip ;

display flussstaerke.l, x.l, y.l ;