$Title Kontinuierliches Huff-Modell
$Ontext

Vorlesung: Service Operations Management
Abschnitt: 2.2 Planung von Standorten und Netzwerken
Problemstellung: Standortplanung von Handelsfilialen in der Ebene

 - Model -

Author: Christoph Schwindt
Date: 18/12/2019

$Offtext

$eolcom//

$include huff_data.gms

******* exaktes Modell *******

variables
   umsatz   Gesamtumsatz der zu platzierenden Einheiten (Zielfunktion)
   a(i,j)   Attraktivitaet von Einheit j in Absatzregion i
   pi(i,j)  Wahlwahrscheinlichkeit von Einheit j in Absatzregion i
   s(j)     Groesse der zu platzierenden Einheit j
   x(j)     x-Koordinate der zu platzierenden Einheit j
   y(j)     y-Koordinate der zu platzierenden Einheit j ;

positive variables a, pi, s ;

equations
   def_umsatz   Definition des Gesamtumsatzes
   def_pi(i,j)  Definition der Wahlwahrscheinlichkeiten
   def_a(i,j)   Definition der Attraktivitaeten
   allokation   Allokation der Groessen zu zu platzierende Einheiten ;

   def_umsatz..          umsatz =e= sum((i,j)$neu(j), bigV(i)*pi(i,j)) ;
   def_pi(i,j)$neu(j)..  pi(i,j) =e= a(i,j)/(sum(jPrime$(not neu(jPrime)), a_ex(i,jPrime))+sum(jPrime$neu(jPrime), a(i,jPrime))) ;
   def_a(i,j)$neu(j)..   a(i,j) =e= s(j)/(abs(x(j)-u(i))+abs(y(j)-v(i))+8/(3*3.141592654)*r(i))**lambda ;
   allokation..          sum(j$neu(j), s(j)) =e= bigS ;

model huff / all / ;

options nlp = lindoglobal
        optcr = 1e-6
        reslim = 60 ;

   x.lo(j) = smin(i, u(i)) ; x.up(j) = smax(i, u(i)) ; // Grenzen fuer Solver
   y.lo(j) = smin(i, v(i)) ; y.up(j) = smax(i, u(i)) ; // Grenzen fuer Solver

solve huff maximzing umsatz using dnlp ;

display umsatz.l, x.l, y.l, s.l ;