$Title Maximum-Covering-Location-Problem
$Ontext

Vorlesung: Service Operations Management
Abschnitt: 2.2 Planung von Standorten und Netzwerken
Problemstellung: Standortplanung oeffentlicher Einrichtungen zur Maximierung des Servicegrads
Quelle: Tafeluebung zur Vorlesung, Aufgabe 5

 - Data -

Author: Rui Guo
Date: 19/12/2019

$Offtext

sets
   i                 Knoten  / i1*i9 /  // Stadtteile und Standorte
   keine_einheit(i)  Knoten in denen keine Einheit errichtet werden soll / i6 / ;

alias (i,j,k) ;

table c(i,j) Entfernung zwischen Standort i und Ortsteil j
       i1  i2  i3  i4  i5  i6  i7  i8  i9
   i1      20  20
   i2          30  35          40
   i3              15
   i4                  20  25  30
   i5                      15
   i6                          35  40
   i7                              20  40
   i8                                  30
   i9                                      ;

   c(j,i)$(c(i,j)>0) = c(i,j) ;

scalars
   d_max  Vorgegebene maximale Entfernung / 30 /
   p      Vorgegebene Anzahl an zu errichtenden Einheiten i / 2 / ;

parameters
   h(i)    Anzahl der Einwohner von Ortsteil i / (i1*i9) 1000 /
   a(i,j)  gleich 1 falls Entfernung zwischen Ortsteil i und Einheit j nicht groesser als die vorgegebene maximale Entfernung d_max ist
   d(i,j)  Entfernung zwischen Standort i und Ortsteil j ;

***** Floyd-Warshall-Algorithmus zur Berechnung kuerzester Weglaengen *****

   d(i,j) = inf ;
   d(i,i) = 0 ;
   d(i,j)$(c(i,j)>0) = c(i,j) ;

   loop(j,
         loop((i,k),
                 if ((d(i,j) < inf) and (d(j,k) < inf) and (d(i,k) > d(i,j) + d(j,k)), d(i,k) = d(i,j) + d(j,k) ; ) ;
         ) ;
   ) ;

   a(i,j) = 0 ;
   a(i,j)$(d(i,j) le d_max) = 1 ;