$Title Maximum-Covering-Location-Problem
$Ontext

Vorlesung: Service Operations Management
Abschnitt: 2.2 Planung von Standorten und Netzwerken
Problemstellung: Standortplanung oeffentlicher Einrichtungen zur Maximierung des Servicegrads

 - Model -

Author: Rui Guo
Date: 19/12/2019

$Offtext

$eolcom//

$include mclp_data.gms

variables
   einwohner  Anzahl ueberdeckter Einwohner (Zielfunktion)
   x(i)       gleich 1 falls im Umkreis von hoechstens d_max um Ortsteil i eine Einheit errichtet wird
   y(j)       gleich 1 falls am Standort j eine Einheit errichtet wird ;

binary variables x, y ;

equations
   def_einwohner  Definition der Anzahl ueberdeckter Einwohner
   bedienung(i)   Keine Bedienung fuer Einwohner des Stadtteils i ausserhalb des vorgegebenen maximalen Umkreises
   anzahl         Festlegung der Anzahl an zu errichtenden Einheiten ;

   def_einwohner..  einwohner =e= sum(i, h(i)*x(i)) ;
   bedienung(i)..   x(i) =l= sum(j, a(i,j)*y(j)) ;
   anzahl..         sum(j, y(j)) =e= p ;

   y.fx(j)$keine_einheit(j) = 0 ;
   x.up(i) = 1 ;

model mclp / all / ;

options mip = cplex
        optcr = 0
        reslim = 60 ;

solve mclp maximizing einwohner using mip ;

display einwohner.l, x.l, y.l ;