$Title Network Design
$Ontext

Vorlesung: Service Operations Management
Abschnitt: 2.2 Planung von Standorten und Netzwerken
Problemstellung: Planung der Verbindungen zwischen gegebenen Standorten

 - Model -

Author: Christoph Schwindt
Date: 19/12/2019

$Offtext

$eolcom//

$include network-design_data.gms

variables
   kosten    Gesamtkosten fuer Errichtung und Betrieb des Netzwerks (Zielfunktion)
   x(h,i,j)  Anzahl auf Relation h ueber Verbindung i-j uebertragener Einheiten
   z(i,j)    Anzahl zu errichtender Einheiten von Verbindung i-j ;

positive variables x ;
integer variables z ;

equations
   def_kosten           Definition der Gesamtkosten
   flusserhaltung(h,i)  Flusserhaltung an Knoten i fuer Relation h
   kapazitaet(i,j)      Kapazitaetsrestriktion fuer Verbindung i-j ;

   def_kosten..              kosten =e= sum((h,i,j)$a(i,j), c(h,i,j)*x(h,i,j)) + sum((i,j)$a(i,j), cfix(i,j)*z(i,j)) ;
   flusserhaltung(h,i)..     sum(j$a(i,j), x(h,i,j)) - sum(j$a(j,i), x(h,j,i)) =e= o(h,i)*b(h)-d(h,i)*b(h) ;
   kapazitaet(i,j)$a(i,j)..  sum(h, r(h,i,j)*x(h,i,j)) =l= u(i,j)*z(i,j) ;

   z.up(i,j) = v(i,j) ; // Maximale Anzahl von Einheiten von Verbindung i-j

model network_design / all / ;

options mip = cplex
        optcr = 1e-6
        reslim = 60 ;

solve network_design minimzing kosten using mip ;

display kosten.l, x.l, z.l ;