$Title p-Zentren-Modell
$Ontext

Vorlesung: Service Operations Management
Abschnitt: 2.2 Planung von Standorten und Netzwerken
Problemstellung: Standortplanung oeffentlicher Einrichtungen zur Optimierung der Erreichbarkeit

 - Model -

Author: Rui Guo
Date: 19/12/2019

$Offtext

$eolcom//

$include p-center_data.gms

variables
   d_max   Groesste Entfernung zwischen einem Standort i und der naechstgelegenen errichteten Einheit j (Zielfunktion)
   x(i,j)  gleich 1 falls Ortsteil i von Einheit an Standort j bedient wird
   y(j)    gleich 1 falls am Standort j eine Einheit errichtet wird ;

binary variables x, y ;

equations
   def_d_max(i)  Definition der maximalen Entfernung
   bedienung(i)  Ortsteil j muss bedient werden
   kopplung(j)   Standort j kann nur bedienen wenn er errichtet wurde
   anzahl        Festlegung der Anzahl an zu errichtenden Einheiten ;

   def_d_max(i)..  d_max =g= sum(j, d(i,j)*x(i,j)) ;
   bedienung(i)..  sum(j, x(i,j)) =e= 1 ;
   kopplung(j)..   sum(i, x(i,j)) =l= card(i)*y(j) ;
   anzahl..        sum(j, y(j)) =e= p ;

model p_center / all / ;

options mip = cplex
        optcr = 0
        reslim = 60 ;

solve p_center minimizing d_max using mip ;

display d_max.l, x.l, y.l ;