$Title Ressourcenbeschraenkte Projektplanung
$Ontext

Vorlesung: Service Operations Management
Abschnitt: 3.2 Projektplanung
Problemstellung: Erstellung eines Projektplans zur Minimierung der Kontaktphasenzeiten
Quelle: Tafeluebung zur Vorlesung, Aufgabe 11

 - Data -

Author: Christoph Schwindt
Date: 25/12/2019

$Offtext

sets
   i              Aktivitaeten / i0*i5 /
   mu             Kontaktphasen / mu1 /
   i_in_mu(mu,i)  Aktivitaeten der Kontaktphasen / mu1.(i1*i4) /
   t              Zeitpunkte / t0*t30 /
   k              Erneuerbare Ressourcen / k1 / ;

alias (h,i,j), (t,tPrime) ;

set a(i,j)  Pfeile im Projektnetzwerk / i0.(i1,i3), i1.(i2,i5), i2.(i1,i4,i5), i3.(i0,i2,i4), i4.(i5), i5.(i0) / ;

parameter
   p(i)          Dauer der Aktivitaet / i0 0, i1 7, i2 4, i3 3, i4 2, i5 0 /
   ES(i)         Fruehester Startzeitpunkt der Aktivitaet i
   LS(i)         Spaetester Startzeitpunkt der Aktivitaet i
   r(i,k)        Inanspruchnahme der erneuerbaren Ressource k durch Aktivitaet i / i0.k1 0, i1.k1 1, i2.k1 1, i3.k1 1, i4.k1 2, i5.k1 0 /
   capital_R(k)  Ressourcenkapazitaet / k1 2 /
   w(mu)         Anzahl der Kunden in Kontaktphase mu / mu1 1 / ;

table
   delta(i,j)  Zeitlicher Mindestabstand zwischen den Startzeitpunkten der Aktivitaeten i und j
          i0     i1     i2     i3     i4     i5
   i0            2             3
   i1                   2                    7
   i2            -4                   1      5
   i3     -4            -3            5
   i4                                        2
   i5     -12                                    ;


parameter
   dist(i,j)  Distanzmatrix ;

***** Floyed-Warshall-Algorithmus zur Berechnung der Distanzen *****

   dist(i,j) = -inf ;
   dist(i,i) = 0 ;
   dist(i,j)$a(i,j) = delta(i,j) ;
   loop(i,
         loop((h,j),
                 if ((dist(h,i)>-inf) and (dist(i,j)>-inf),
                         if (dist(h,j) < dist(h,i)+dist(i,j), dist(h,j) = dist(h,i)+dist(i,j) ; ) ;
                 ) ;
         ) ;
   ) ;

   ES(i) = dist('i0',i) ;
   LS(i) = -dist(i,'i0') ;