$Title Vorlesungsplanung
$Ontext

Vorlesung: Service Operations Management
Abschnitt: 3.4 Timetabling
Problemstellung: Zeitplanung fuer Vorlesungen

 - Model -

Author: Rui Guo
Date: 10/12/2019

$Offtext

$eolcom//

$include university-course-scheduling_data.gms

variables
   tBar    Benoetigte Anzahl an Zeitbloecken t
   y(j,t)  gleich 1 falls Kurs j in Zeitblock t stattfindet ;

binary variables y ;

equations
   def_tBar(j,t)                          Definition der Anzahl an Zeitbloecken
   perioden_kurs(j)                       Zuordnung von Perioden zu Kurs j
   konfliktfrei_studiengangsemester(i,t)  Zuweisung von hoechstens einem Kurs in Zeitblock t an Studiengangsemester i
   konfliktfrei_dozent(j,jPrime,k,t)      Keine Zuweisung verschiedener Kurse j und jPrime in Zeitblock t an Dozenten k ;

   def_tBar(j,t)..                                             tBar =g= ord(t)*y(j,t) ;
   perioden_kurs(j)..                                          sum(t, y(j,t)) =e= p(j);
   konfliktfrei_studiengangsemester(i,t)..                     sum(j, a(i,j)*y(j,t)) =l= 1;
   konfliktfrei_dozent(j,jPrime,k,t)$(not sameas(j,jPrime))..  y(j,t)*x(j,k) + y(jPrime,t)*x(jPrime,k) =l= 1;

model university_course_scheduling / all / ;

options mip = cplex
        optcr = 0
        reslim = 60 ;

solve university_course_scheduling minimzing tBar using mip ;

display tBar.l, y.l ;